TITLE	FILBRK

	ENTRY	FILBRK
	EXTERN	DEV
	INTERN	FNAM,DLK,ASTR

	WD=7

ASTR:	ASCIZ/
*/
ZERSUB:	Z
	MOVE	PT2
	MOVEM	PT
	SETZB	1,WD
	JRST	@ZERSUB

COMSUB:	CAIN	15
	JRST	[MOVEI	10,EOJ
	JRST	(16)]
	CAIN	"["
	JRST	[MOVEI	10,GTPROJ
	JRST	(16)]
	CAIE	"."
	JRST	2(16)
	MOVEI	10,GTEXT
	JRST	(16)

FSUB:	JSP	16,COMSUB
	MOVEM	WD,FNAM
	JRST	(10)
	CAIL	1,6
	JRST	.+3
	SUBI	40
	IDPB	PT
	AOJA	1,(15)

ACS:	BLOCK	20

FNAM:DLK:	Z
EXT:	Z
	Z
PPN:	Z
PT:	POINT	6,WD
PT2:	POINT	6,WD

FILBRK:	Z
	MOVEM	17,ACS+17
	MOVEI	17,ACS
	BLT	17,ACS+16
ST:	MOVSI	'DSK'
	MOVEM	DEV
	SETZB	FNAM
	MOVEM	FNAM+1
	MOVEM	FNAM+2
	MOVEM	FNAM+3
	OUTSTR	ASTR
GTDEV:	JSR	ZERSUB
	MOVEI	15,.+1
	INCHWL
	CAIE	":"
	JRST	FSUB
	MOVEM	WD,DEV
GTFNAM:	JSR	ZERSUB
	MOVEI	15,.+1
	INCHWL
	JRST	FSUB
GTEXT:	JSR	ZERSUB
	INCHWL
	JSP	16,COMSUB
	MOVEM	WD,EXT
	JRST	(10)
	CAIL	1,3
	JRST	.+3
	SUBI	40
	IDPB	PT
	AOJA	1,GTEXT+1

GTPROJ:	SETZB	1,2
	INCHWL
	CAIN	","
	JRST	GTPROG
	SUBI	60
	CAILE	7
	JRST	ERR
	ASH	2,3
	JOV	ERR
	HRLZS
	ADD	2,
	JOV	ERR
	JRST	GTPROJ+1

GTPROG:	INCHWL
	CAIE	15
	CAIN	"]"
	JRST	COMBIN
	SUBI	60
	CAILE	7
	JRST	ERR
	ASH	1,3
	JOV	ERR
	HRLZS
	ADD	1,
	JOV	ERR
	JRST	GTPROG
COMBIN:	HLR	2,1
	MOVEM	2,PPN
EOJ:	CLRBFI
	MOVSI	17,ACS
	BLT	17,16
	MOVE	17,ACS+17
	JRA	16,(16)
ERR:	CLRBFI
	OUTSTR	[ASCIZ/?IMPROPER SYNTAX?
/]
	JRST	ST
	END